Comparing And Retrieving Scores

Introduction ​

Sourced By Bedrock Commands Community Discord

In this guide, you will learn how to test for targets of matching scores / targets with the highest or lowest score.

Get Highest Score ( > ) ​

Commands:

## Get Highest Score
scoreboard players operation Highest <objective> > * <objective>

## Your Commands Here (Example)
execute as <target> if score @s <objective> = Highest <objective> run <command>

Command 1: This command compares the Highest score with every other tracked score in the specified objective, and if the Highest score is lesser than the one being compared to, then the Highest score will be assigned the value of that score. To illustrate:

No change when Highest score is compared to player 2 after player 1 (since 10 is already greater than 5).

Command 2: This command can be modified or expanded. It allows you to run your desired command if the <target> score is equal to Highest score.

• Note: Use @p or @e [c=1] in place of <target> if you want to limit your selection to only one.

Example:

## Get Highest Score
scoreboard players operation Highest kills > * kills

## Tag Players with the Most Kills
tag @a remove topKills
execute as @a if score @s kills = Highest kills run tag @s add topKills

Get Lowest Score ( < ) ​

Commands:

## Get Lowest Score
scoreboard players operation Lowest <objective> < * <objective>

## Your Commands Here
execute as <target> if score @s <objective> = Lowest <objective> run <command>

Command 1: This command compares the Lowest score with every other tracked score in the specified objective, and if the Lowest score is greater than the one being compared to, then the Lowest score will be assigned the value of that score. To illustrate:

No change when Lowest score is compared to player 3 after player 2 (since 50 is already less than 200).

Command 2: This command can be modified or expanded. It allows you to run your desired command if the <target> score is equal to Lowest score.

• Note: Use @p or @e [c=1] in place of <target> if you want to limit your selection to only one.

Example:

## Get Lowest Score
scoreboard players operation Lowest distance_travelled < * distance_travelled

## Tag Players with the Least Distance Travelled
tag @a remove eliminate
execute as @a if score @s distance_travelled = Lowest distance_travelled run tag @s add eliminate

Get Matching Scores ( = ) ​

This command compares the executing target's score with other selected targets. It runs the specified command for each target with a matching score.

Command:

execute as @a at @s at @a [rm=0.01] if score @s <objective> = @p <objective> run say @s and @p have matching scores!

Visualisation:

Example 1: Teleport pet to owner if farther than 6 blocks:

## Teleport to Owner
execute as @e [tag=pet] at @s at @a [rm=7] if score @s id = @p id run tp @s @p

Example 2: Set plot owner to Creative mode and others to Adventure mode:

## Set Owners to Creative Mode
execute as @e [tag=plot] at @s at @a [r=16] if score @s id = @p id run gamemode c @p [m=!c]

## Set Non-Owners to Adventure Mode
execute as @e [tag=plot] at @s at @a [r=16] unless score @s id = @p id run gamemode a @p [m=!a]